home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 24 / CU Amiga Magazine's Super CD-ROM 24 (1998)(EMAP Images)(GB)(Track 1 of 2)[!][issue 1998-07].iso / InitCD < prev    next >
AmigaDOS Script File  |  1998-05-22  |  6KB  |  188 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14. ;
  15. ; Version 1.4 - Added section to copy CUCDfile and IDer.prefs to hard drive if not already present
  16.  
  17. Assign CUCD: :
  18.  
  19. ;;; Make some commands resident to speed up things on CD32s in particular
  20. Resident >NIL: CUCD:C/RequestChoice PURE
  21. Resident >NIL: CUCD:rexxc/rx PURE
  22. Resident >NIL: CUCD:C/Version PURE
  23. ;;;
  24. ;;; Exit if InitCD has been run, otherwise ask
  25. If {arg} EQ "CHECK"
  26.     If $CDInit EQ TRUE
  27.         Skip END
  28.     Else
  29.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  30.         If $init EQ 0
  31.             Skip END
  32.             EndIf
  33.         EndIf
  34.     EndIf
  35. ;;;
  36. ;;; Give option to run UninitCD
  37. If $CDInit EQ TRUE
  38.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  39.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  40.         Skip END
  41.         EndIf
  42.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  43.     If $remass EQ 1
  44.         execute UnInitCD
  45.         EndIf
  46.     Skip END
  47.     EndIf
  48. ;;;
  49. ;;; Set some system assigns and paths
  50. Assign WWW:             CUCD:CUCD/WWW
  51. Assign tcpdldir:        CUCD:CUCD/WWW
  52. Assign GM:              CUCD:CDsupport/GMPlay ADD
  53. Assign CUCDNews:        CUCD:CUCD/Online/News
  54. Assign Twist:           CUCD:CUCD/Magazine/Issues
  55. Assign TwistIcon:       Twist:Icons
  56. Path GM: ADD
  57. ;;;
  58. ;;; Add MUI if no MUI installed.
  59. Assign MUI: EXISTS >NIL:
  60. IF WARN
  61.     Assign MUI:    CUCD:CDsupport/MUI
  62.     Assign Libs:   MUI:Libs ADD
  63.     Assign LOCALE: MUI:Locale ADD
  64.     Assign HELP: exists >NIL:
  65.     If NOT WARN
  66.         Dir >NIL: HELP:
  67.         EndIf
  68.     Assign HELP:   MUI:Docs ADD
  69. Else
  70.     :C/UpdateCopy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE DEEP
  71.     EndIf
  72. ;;;
  73. ;;; Set assigns and paths for programs on this CD
  74. Execute CUCD:S/ThisCD
  75. ;;;
  76. ;;;BEGIN ClassAct
  77. CUCD:C/CAPrefs >NIL:
  78. ;;;END ClassAct
  79. ;;; Commands to be run only if booting from CD
  80. IF $CDBoot EQ TRUE
  81.     Run <NIL: >NIL: C:NewIcons
  82.     CUCD:C/DefIcons
  83.  
  84.     ; Run these only if booting from a real CD32
  85.     Version >NIL:
  86.     if $kickstart EQ "40.60"
  87.         ;C:CD2XSpeed
  88.         C:NoReset
  89.         endif
  90.  
  91.     ; Allow alternative screenmodes
  92.     if $CUCDscreen EQ "NTSC"
  93.         :Storage/Monitors/NTSC
  94.         :Prefs/ScreenMode from :Prefs/Presets/NTSC USE
  95.         :Prefs/Input from :Prefs/Presets/USkey USE
  96.         setenv VisageOpts MONITOR=NTSC
  97.         endif
  98.     if $CUCDscreen EQ "VGA"
  99.         :Storage/Monitors/DblPAL
  100.         :Prefs/ScreenMode from :Prefs/Presets/VGA USE
  101.         setenv VisageOpts MONITOR=DblPAL
  102.         endif
  103.     unsetenv CUCDscreen
  104. ;;;
  105. ;;; All this is only needed when not booting from the CD
  106. Else
  107.     ; Start arexx if not running
  108.     CUCD:rexxc/rx "address command" >NIL:
  109.     If WARN
  110.         CUCD:System/RexxMast >NIL:
  111.         EndIf
  112.     Run >NIL: RequestChoice "InitCD" "Setting up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on the Workbench." " OK "
  113.     Assign DEVS:    CUCD:Devs ADD
  114.     Assign Fonts:   CUCD:Fonts ADD
  115.     Assign Libs:    CUCD:Libs ADD
  116.     Assign L:       CUCD:L ADD
  117.     Assign S:       CUCD:S ADD
  118.     Assign LIBS:    CUCD:Classes ADD
  119.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  120.  
  121.     ; Make environment variables defined on CD available to system
  122.     Failat 21
  123.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  124.     ; For HappyENV users
  125.     If FAIL     
  126.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  127.         EndIf
  128.  
  129.     ;Start NewIcons if not already running
  130.     If $NoNewIcons NOT EQ TRUE
  131.         CUCD:C/isnirunning
  132.         If NOT WARN
  133.             Run <NIL: >NIL: CUCD:C/NewIcons
  134.             CUCD:C/DefIcons
  135.             EndIf
  136.         EndIf
  137.  
  138.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  139.     Version >NIL: C:LoadWB 43
  140.     If WARN
  141.        C:LoadWB NEWPATH
  142.     Else
  143.         Version >NIL: C:LoadWB 60
  144.         If NOT WARN
  145.             C:LoadWB NEWPATH
  146.             EndIf
  147.         EndIf
  148.  
  149.     ; Give option for setting CD preferences, make sure CUCDfile and IDer
  150.     ; are in basic command path, so it will run without InitCD
  151.     which >NIL: CUCDfile
  152.     if WARN
  153.         Copy >NIL: CUCD:C/CUCDfile C: CLONE
  154.         EndIf
  155.     which >NIL: IDer
  156.     if WARN
  157.         Copy >NIL: CUCD:C/IDer C: CLONE
  158.         EndIf
  159.     ; ensure IDer.prefs are available
  160.     If NOT EXISTS ENV:IDer.prefs
  161.         If NOT EXISTS S:IDer.prefs
  162.             Version >NIL: version 39
  163.             If NOT WARN
  164.                 Copy >NIL: CUCD:S/IDer.prefs S:IDer.prefs
  165.                 set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  166.                 If $edit EQ 1
  167.                     cd CUCD:S
  168.                     :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  169.                 Else
  170.                     RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  171.                     EndIf
  172.             Else
  173.                 Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  174.                 EndIf
  175.             EndIf
  176.         EndIf
  177.     EndIf
  178. ;;;
  179. SetEnv CDInit TRUE
  180.  
  181. LAB END
  182.  
  183. ;;; Remove commands made resident earlier
  184. Resident >NIL: RequestChoice REMOVE
  185. Resident >NIL: rx REMOVE
  186. Resident >NIL: Version REMOVE
  187. ;;;
  188.